initial structure + nix build (#1)

(incl. cross-compiling)
2024-11-27 20:57:43 +01:00
parent f4012856a4
commit b95d7ecfb2
8 changed files with 1158 additions and 7 deletions
--- a/flake.nix
+++ b/flake.nix
@@ -0,0 +1,86 @@
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+    crane.url = "github:ipetkov/crane";
+    fenix = {
+      url = "github:nix-community/fenix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+
+  outputs = { nixpkgs, flake-utils, fenix, crane, ... }:
+    flake-utils.lib.eachDefaultSystem (system:
+      let
+        pkgs = nixpkgs.legacyPackages.${system};
+        # Using stable toolchain as base
+        toolchain = with fenix.packages.${system};
+          combine [
+            minimal.rustc
+            minimal.cargo
+            targets.x86_64-pc-windows-gnu.latest.rust-std
+        ];
+        craneLib = (crane.mkLib pkgs).overrideToolchain toolchain;
+
+        # Common build inputs for both native and cross compilation
+        commonArgs = {
+          src = craneLib.cleanCargoSource ./.;
+          cargoArtifacts = craneLib.buildDepsOnly {
+            src = craneLib.cleanCargoSource ./.;
+          };
+        };
+
+        # Native build
+        timr = craneLib.buildPackage commonArgs;
+
+        # Windows cross-compilation build
+        # @see https://crane.dev/examples/cross-windows.html
+        crossBuild = craneLib.buildPackage {
+          src = craneLib.cleanCargoSource ./.;
+
+          strictDeps = true;
+          doCheck = false;
+
+          CARGO_BUILD_TARGET = "x86_64-pc-windows-gnu";
+
+          # fixes issues related to libring
+          TARGET_CC = "${pkgs.pkgsCross.mingwW64.stdenv.cc}/bin/${pkgs.pkgsCross.mingwW64.stdenv.cc.targetPrefix}cc";
+
+          #fixes issues related to openssl
+          OPENSSL_DIR = "${pkgs.openssl.dev}";
+          OPENSSL_LIB_DIR = "${pkgs.openssl.out}/lib";
+          OPENSSL_INCLUDE_DIR = "${pkgs.openssl.dev}/include/";
+
+          depsBuildBuild = with pkgs; [
+            pkgsCross.mingwW64.stdenv.cc
+            pkgsCross.mingwW64.windows.pthreads
+          ];
+        };
+      in
+      {
+        packages = {
+          inherit timr;
+          default = timr;
+          windows = crossBuild;
+        };
+
+        # Separate artifacts for CI caching
+        checks = {
+          inherit timr;
+          cargoArtifacts = commonArgs.cargoArtifacts;
+        };
+
+        # Development shell with all necessary tools
+        devShells.default = pkgs.mkShell {
+          buildInputs = with pkgs; [
+            rust-analyzer
+            clippy
+            rustfmt
+            toolchain
+          ];
+
+          inherit (commonArgs) src;
+          RUST_SRC_PATH = "${toolchain}/lib/rustlib/src/rust/library";
+        };
+      });
+}